Cosa sono i feed RSS

I feed RSS sono file XML, che seguono degli standard per garantire l'accesso e la lettura del loro contenuti a browser, Feed Reader e a script (nel nostro caso ASP).
Questi contengono informazioni su news, articoli o altro ancora... Per ogni articolo viene fornito il titolo, una descrizione, l'autore, la data e l'ora di pubblicazione, nonche' il link per leggere l'intero articolo.

Vengono molto utilizzati dai blog, ma anche da siti come WebMasterPoint.org che vogliono offrire ai propri utenti gli ultimi aggiornamenti in tempo reale.

Lo script ASP per leggere i feed ASP

Con lo script asp sotto presentato potrete leggere e pubblicare direttamente sul vostro sito web le news di WebMasterPoint.org (ma va bene per qualsiasi feed RSS di altri siti) o volende gli aggiornamenti, i messaggi del forum o gli script (per altre informazioni leggi la nostra pagina dei Feed RSS di WebMasterPoint.org)

Il codice

<lu>
<%

'Utilizzo oggetto DOM per caricare il file xml (feed rss)
Set objXML = Server.CreateObject("msxml2.DOMDocument.3.0")

objXML.async = false
objXML.setProperty "ServerHTTPRequest", True
objXML.validateOnParse =false
objXML.preserveWhiteSpace = false

' Carico news di WebMasterPoint.org
caricoFile = objXML.Load("http://www.webmasterpoint.org/rss/news.xml")

' ALTRI FEED UTILI
' Ultimi articoli di WebMasterPoint.org: http://www.webmasterpoint.org/rss/articoli.xml
' Ultimi post del forum: http://forum.webmasterpoint.net/external.php?type=RSS
' Ultimi post del forum ASP: http://forum.webmasterpoint.net/external.php?type=RSS&forumids=24
' Ultimi post del forum PHP: http://forum.webmasterpoint.net/external.php?type=RSS&forumids=28
' Ultimi post del forum Flash: http://forum.webmasterpoint.net/external.php?type=RSS&forumids=13
' Ultimi post del forum Snitz Forum: http://forum.webmasterpoint.net/external.php?type=RSS&forumids=25
' Ultimi post del forum Off Topics: http://forum.webmasterpoint.net/external.php?type=RSS&forumids=19

' Per tutti i Feed RSS di WebMasterPoint.org: http://www.webmasterpoint.org/rss/rss.asp

' Controllo se e' stato caricato il file
If Not caricoFile Then
' In caso di errore avviso quale errore si e' verificato
Response.write "<p><strong>Errore</strong><br>: " & objXML.parseError.errorCode & "<br>"
Response.Write "Linea: " & objXML.parseError.line & "/"
Response.WRite "Colonna: " & objXML.parseError.linepos & "</p>"
Else
' In caso non vi sia nessun errore, proseguo e carico le info del file xml (feed rss)
Set Nodo = objXML.getElementsByTagName("item")

For Each objNodi In Nodo
' Sfoglio i nodi
For Each objNodo In objNodi.childNodes
Select Case objNodo.nodeName
Case "title"
titolo = objNodo.firstChild.nodevalue
Case "link"
link = objNodo.firstChild.nodevalue
Case "description"
descrizione = objNodo.firstChild.nodevalue
Case "dc:date"
data = objNodo.firstChild.nodevalue
data = Replace(data,"T"," alle ")
data = Replace(data,"+00:00","")
End Select

Next

' VISUALIZZO LA NOTIZIA - E' possibile modificare il codice html delle 3 righe qui sotto, per formattare le news come si desidera
Response.write ("<li><a href=""" & link & """ title=""Leggi: " & titolo & " - Autore: Redazione di WebMasterPoint.org"" target=""_blank"">")
Response.Write (titolo & "</a> <font color=""#CCCCCC"">" & data & "</font><br>" & descrizione & " (<a href=""" & link & """ title=""Leggi: " & titolo)
Response.Write (" - Autore: Redazione di WebMasterPoint.org"" target=""_blank"">Leggi tutto...</a>)</li>")

Next

set Nodo = Nothing
End if
%>
</ul>

Modificare l'output

E' possibile modificare l'output dello script (il modo di visualizzare gli articoli) in due modi:

• Con i CSS
• con il codice html

Utilizzando i css e' possibile modificare l'output impostando uno stile all'elenco <
Mentre per modifiche al codice html, basta cambiare il codice all'interno dei tre Response.Write che si trovano alla fine dello script, sotto a ' VISUALIZZO LA NOTIZIA

Per qualsiasi domanda, chiedete aiuto gratuitamente sul nostro forum: http://forum.webmasterpoint.net

Segnala questo articolo ai tuoi amici su Facebook